#!/usr/bin/perl -w
######################################################################
# This Perl script will generate a geometry file to use
# with IceCube simulations.
# Author: Joakim Edsjo, edsjo@physto.se
# Date: December 29, 1999
######################################################################

use Getopt::Std;

######### SETUP and INPUT ##########

$ver="1.0, December 29, 1999";

### Parse input arguments

getopts('m:s:r:R:o:v:p:h',\%opts);

if ($opts{"h"}) {       # Help required
    print<<END;
Usage: gen-submod.pl [arguments] [geometry-file]

gen-submod.pl generates a geometry file with a submodular layout. The output is
written to the given geometry file. If no geometry file is given, a default
name is generated.

Arguments:
   -s number  Number of strings in each submodule. Default: 10
   -r number  Radius (in m) of outer strings in a submodule. Default: 90 m.
   -m number  Number of submodules. Default: 8
   -R number  Radius (in m) of the other submodules. Default: 350 m.
   -o number  Number of OMs on each string. Default: 60
   -v number  Vertical spacing between OMs (meters). Default: 16 m.
   -p number  What pulse shape to use. Default: 5 (square pulse)
   -h         Show this help.

Joakim Edsjo, edsjo\@physto.se
END
    die "-- gen-submod version $ver --\n";
} 

if ($opts{'s'}) {
    $stringspersub=$opts{'s'};
} else {
    $stringspersub=10;
}

if ($opts{'r'}) {
    $radiusinsub=$opts{'r'};
} else {
    $radiusinsub=90;
}

if ($opts{'m'}) {
    $numberofsubs=$opts{'m'};
} else {
    $numberofsubs=8;
}

if ($opts{'R'}) {
    $radiusbetweensubs=$opts{'R'};
} else {
    $radiusbetweensubs=350;
}

if ($opts{'o'}) {
    $omperstring=$opts{'o'};
} else {
    $omperstring=60;
}

if ($opts{'v'}) {
    $verticalspacing=$opts{'v'};
} else {
    $verticalspacing=16;
}

if ($opts{'p'}) {
    $pulseshape=$opts{'p'};
} else {
    $pulseshape=5;
}

if (@ARGV>0) {   # output file given
   $geofile=shift;
} else {         # generate output file name
   $geofile="ice.${stringspersub}-${radiusinsub}m"
    . "-${numberofsubs}-${radiusbetweensubs}m"
    . ".${omperstring}.${verticalspacing}m";
   if ($pulseshape == 5) {
       $geofile .= ".sp.geo";
   } else {
       $geofile .= ".${pulseshape}.geo";
   }
   $geofile =~ s/\s+//g;
}

print "Welcome to gen-submod.pl\n";
print "Will create the geometry file: $geofile\n";

open(GEO,">$geofile") || 
    die "Can't open geometry file $geofile for writing: $!\n";

geo_header();

$zlow=-($omperstring-1)*$verticalspacing/2;

$omi=0;
for ($subi=0; $subi<$numberofsubs; $subi++) {
    if ($subi==0) {
        $sub_x=0;
        $sub_y=0;
    } else {
        $phi=$subi/($numberofsubs-1.0)*2*3.1415926535;
        $sub_x=$radiusbetweensubs*cos($phi);
        $sub_y=$radiusbetweensubs*sin($phi);
    }
    geo_sub($sub_x,$sub_y);
}

############### SUBROUTINES ###############

sub geo_header {  # Print geomtry file header to output file.
    $date=localtime();
    print GEO <<END;
V 1.20
c ICE^3 geometry created by gen-submod.pl version $ver
c Generation date: $date
c Joakim Edsjo, edsjo\@physto.se
c
c
c Explanation of the shortcuts:
c X,Y,Z  : coordinates of OM in [cm]
c TU     : Orientation of OM -1.0 is downlooking, 1.0 is uplooking
c          (no other values possible)
c TH     : Threshold of this channel in [mV]
c 1pe/mV : Position of the 1-pe peak in [mV]
c Hz     : Noise rate of this OM in [Hz]
c m^2    : Projected area (x-y plane) of the OM in [m^2]
c rsens  : Relative sensitivity of PMT to the average PMT
c          (taken from data sheet)
c t0     : Time the signal needs to travel the cable in [ms]
c app    : Probability that an afterpuls will follow the puls
c apdt   : Typical time between puls and afterpulse
c pulse  : Pulse shape number (from puls.txt)
c caladc : Delayed-pulse ADC calibration (1pe/mV) in [mV]
c
c
c rsens, app and apdt are set to educated guesses
c units x,y,z [cm], 1=up, t0=[ns]
c
c#    X       Y       Z    TU  TH  1pe/mV Hz   m^2  rsens  t0  app apdt pulse caladc
END
}

##### 
sub geo_line {  # print one line to the output file
    my ($omi,$x,$y,$z)=@_;
    printf GEO " %i %i. %i. %i. %s %i %s",
    $omi, $x*100, $y*100, $z*100,
    "-1. 100. 322. 500. 0.0444 1. 107. 0.06 6000.",
    $pulseshape,"100.\n";
}

#####
sub geo_sub {   # Generate one submodule
    my ($sub_x,$sub_y)=@_;
    for ($si=0; $si<$stringspersub; $si++) {
        if ($si==0) {
            $x=$sub_x;
            $y=$sub_y;
        } else {
            $phi=$si/($stringspersub-1.0)*2*3.1415926535;
            $x=$sub_x + $radiusinsub*cos($phi);
            $y=$sub_y + $radiusinsub*sin($phi);
        }
        for ($zi=0; $zi<$omperstring; $zi++) {
	    $z=$zlow+$zi*$verticalspacing;
            $omi++;
            geo_line($omi,$x,$y,$z);
	}
    }
}